SPARQL 1.1 · Linked Open Data

Biblioteca INTI
SPARQL Endpoint INTI Library
SPARQL Endpoint

La Biblioteca INTI publica su Tesauro, Diccionarios Técnicos, Guía de Fuentes y los metadatos de su Catálogo Bibliográfico como datos abiertos y enlazados (Linked Data), siguiendo estándares W3C (SKOS, RDF, SPARQL 1.1). El Tesauro, además, está enlazado a la nube global de Linked Open Data mediante equivalencias con Wikidata. Cada colección es un dataset independiente, consultable directamente por HTTP.

The INTI Library publishes its Thesaurus, Technical Dictionaries, Sources Guide and the metadata of its Bibliographic Catalog as open Linked Data, following W3C standards (SKOS, RDF, SPARQL 1.1). The Thesaurus is additionally linked to the global Linked Open Data cloud through Wikidata equivalences. Each collection is an independent dataset, queryable directly over HTTP.

4 endpoints — uno por dataset

4 endpoints — one per dataset

Catálogo https://biblioteca.inti.gob.ar/sparql/Catalogo/query

Tesauro https://biblioteca.inti.gob.ar/sparql/Tesauro/query

Diccionarios https://biblioteca.inti.gob.ar/sparql/Diccionarios/query

Fuentes https://biblioteca.inti.gob.ar/sparql/Fuentes/query

SPARQL 1.1 Lectura sin autenticaciónRead access, no authentication RDF · SKOS · JSON-LD

¿Buscás un libro, una norma o algún documento puntual? Te va a resultar más cómodo usar el catálogo de búsqueda de la Biblioteca. Esta página es para quienes quieran explorar nuestros datos de forma técnica, con SPARQL. Looking for a book, standard, or a specific document? You'll probably find it more convenient to use the Library's search catalog. This page is for anyone who wants to explore our data more technically, using SPARQL.

Datasets disponiblesAvailable Datasets

Cuatro datasets independientes en Apache Jena Fuseki, cada uno con su propio endpoint de consulta.

Four independent datasets on Apache Jena Fuseki, each with its own query endpoint.

Catálogo Bibliográfico

Bibliographic Catalog

Registros de libros, revistas y normas técnicas: título, autor, tipo de material, materia y signatura.

Records of books, journals and technical standards: title, author, material type, subject and shelf mark.

Endpoint/sparql/Catalogo/query

Prefijointi:

Dublin Core y BIBFRAME (estándares para describir libros y documentos)Dublin Core and BIBFRAME (standards for describing books and documents)

Es el único dataset que el sitio también consulta en vivo para su propio buscador.The only dataset the site itself also queries live for its own search.

Tesauro INTI

INTI Thesaurus

Vocabulario controlado SKOS: conceptos técnicos, jerarquías (broader/narrower), términos relacionados, etiquetas alternativas y enlaces a Wikidata.

SKOS-based controlled vocabulary: technical concepts, hierarchies (broader/narrower), related terms, alternative labels and Wikidata links.

Endpoint/sparql/Tesauro/query

Namespace.../tesauro/

SKOS (estándar para tesauros) · enlazado a WikidataSKOS (thesaurus standard) · linked to Wikidata

Diccionarios Técnicos

Technical Dictionaries

Términos de diccionarios especializados (caucho, cobre, nodest) con definiciones y equivalentes en inglés y portugués.

Terms from specialized dictionaries (rubber, copper, nodest) with definitions and English/Portuguese equivalents.

Endpoint/sparql/Diccionarios/query

Prefijointi:

SKOS multi-idioma (mismo estándar del Tesauro) · enlazado a Wikidata/PubChemMulti-language SKOS (same standard as the Thesaurus) · linked to Wikidata/PubChem

Guía de Fuentes

Sources Guide

Directorio curado de bases científicas y portales especializados, organizados por área temática.

Curated directory of scientific databases and specialized portals, organized by subject area.

Endpoint/sparql/Fuentes/query

Prefijointi:

SKOS (mismo estándar del Tesauro)SKOS (same standard as the Thesaurus)

¿Vas a listar estos datasets en tu propio catálogo o herramienta? La ficha técnica completa de los 4 (tripletas, vocabularios, licencia) está en formato VoID/DCAT, pensada para ese uso. Listing these datasets in your own catalog or tool? The full technical description of all 4 (triple counts, vocabularies, license) is available in VoID/DCAT format, built for that purpose.

Prefijos y VocabulariosPrefixes & Vocabularies

Los que realmente usan los datos — declaralos en tus consultas SPARQL.

The ones the data actually uses — declare them in your SPARQL queries.

Prefijos RDF usados en los datasets de la Biblioteca INTI
Prefijo / Prefix	URI	DescripciónDescription
inti:	http://biblioteca.inti.gob.ar/ontologia#	Ontología propia de la Biblioteca (Catálogo, Diccionarios, Fuentes)The Library's own ontology (Catalog, Dictionaries, Sources)
skos:	http://www.w3.org/2004/02/skos/core#	Simple Knowledge Organization System
dcterms:	http://purl.org/dc/terms/	Dublin Core Terms
bf:	http://id.loc.gov/ontologies/bibframe/	BIBFRAME
schema:	http://schema.org/	Schema.org
rdfs:	http://www.w3.org/2000/01/rdf-schema#	RDF Schema
rdf:	http://www.w3.org/1999/02/22-rdf-syntax-ns#	RDF Syntax
wd:	http://www.wikidata.org/entity/	Entidades Wikidata (destino de skos:exactMatch)Wikidata entities (skos:exactMatch target)

Consultas de ejemploExample Queries

Las marcadas EN VIVO están tomadas literalmente del código del sitio (son las que usa la propia Biblioteca). Las marcadas ILUSTRATIVA siguen el modelo de datos real pero fueron escritas para este ejemplo.

Queries marked LIVE are taken literally from the site's own code. Queries marked ILLUSTRATIVE follow the real data model but were written for this example.

Catálogo

Catalog

Tesauro

Thesaurus

Diccionarios

Dictionaries

Guía de Fuentes

Sources Guide

Buscar registros por título

Search records by title

Con título "curado" opcional (inti:tituloVisualizacion) sobre el título crudo.

With optional "curated" title (inti:tituloVisualizacion) over the raw title.

Catálogo En vivoLive

PREFIX schema: <http://schema.org/>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX inti: <http://biblioteca.inti.gob.ar/ontologia#>

SELECT ?uri ?titulo ?tituloVis
WHERE {
  { ?uri schema:name ?titulo . } UNION { ?uri dcterms:title ?titulo . }
  OPTIONAL { ?uri inti:tituloVisualizacion ?tituloVis . }
  FILTER(CONTAINS(LCASE(STR(?titulo)), "acero"))
}
LIMIT 20

Contar registros por tipo de material

Count records by material type

Estadística de la colección agrupada por rdf:type.

Collection statistics grouped by rdf:type.

Catálogo IlustrativaIllustrative

PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT ?tipo (COUNT(?registro) AS ?total)
WHERE {
  ?registro rdf:type ?tipo .
}
GROUP BY ?tipo
ORDER BY DESC(?total)

Verificar que el dataset responde

Check the dataset is responding

El propio sitio usa esta consulta ASK como chequeo de salud del servicio.

The site itself uses this ASK query as a service health check.

Tesauro En vivoLive

ASK { ?s ?p ?o }

Listar conceptos del Tesauro

List Thesaurus concepts

Etiquetas preferentes en español, ordenadas alfabéticamente.

Preferred labels in Spanish, alphabetically ordered.

Tesauro IlustrativaIllustrative

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?concepto ?etiqueta
WHERE {
  ?concepto a skos:Concept ;
             skos:prefLabel ?etiqueta .
  FILTER(LANG(?etiqueta) = "es")
}
ORDER BY ASC(STR(?etiqueta))
LIMIT 50

Términos más amplios (jerarquía ascendente)

Broader terms (upward hierarchy)

Navega hacia arriba en la jerarquía SKOS con skos:broader+.

Navigate upward in the SKOS hierarchy with skos:broader+.

Tesauro IlustrativaIllustrative

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

# Reemplazá el URI del concepto por uno real de tu instancia
SELECT ?termMasAmplio ?etiqueta
WHERE {
  <https://biblioteca.inti.gob.ar/tesauro/EJEMPLO>
      skos:broader+ ?termMasAmplio .
  ?termMasAmplio skos:prefLabel ?etiqueta .
  FILTER(LANG(?etiqueta) = "es")
}

Conceptos enlazados a Wikidata

Concepts linked to Wikidata

Vía skos:exactMatch (no owl:sameAs).

Via skos:exactMatch (not owl:sameAs).

Tesauro IlustrativaIllustrative

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?concepto ?etiqueta ?wikidataURI
WHERE {
  ?concepto a skos:Concept ;
             skos:prefLabel ?etiqueta ;
             skos:exactMatch ?wikidataURI .
  FILTER(LANG(?etiqueta) = "es")
  FILTER(STRSTARTS(STR(?wikidataURI), "http://www.wikidata.org/entity/"))
}
ORDER BY ?etiqueta
LIMIT 100

Término con traducciones y definición

Term with translations and definition

skos:prefLabel es multi-idioma (@es, @en, @pt) en este dataset.

skos:prefLabel is multi-language (@es, @en, @pt) in this dataset.

Diccionarios IlustrativaIllustrative

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?termES ?termEN ?definicion
WHERE {
  ?entrada skos:prefLabel ?termES ;
           skos:prefLabel ?termEN ;
           skos:definition ?definicion .
  FILTER(LANG(?termES) = "es")
  FILTER(LANG(?termEN) = "en")
  FILTER(LANG(?definicion) = "es")
}
LIMIT 30

Fuentes por categoría

Sources by category

Lista fuentes con nombre, URL y categoría temática.

Lists sources with name, URL and subject category.

Fuentes IlustrativaIllustrative

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX inti: <http://biblioteca.inti.gob.ar/ontologia#>

SELECT ?nombre ?url ?categoria
WHERE {
  ?fuente a inti:Fuente ;
           skos:prefLabel ?nombre ;
           inti:url ?url ;
           inti:categoria ?categoria .
}
ORDER BY ?categoria ?nombre
LIMIT 50

¿Y si necesito cruzar dos datasets?What if I need to combine two datasets?

Como cada dataset vive en un endpoint propio, no existe una sola consulta SPARQL que los una a los dos. La cláusula SERVICE (que permitiría federar consultas entre endpoints) no está disponible. La forma correcta —y la que usa la propia Biblioteca en su buscador— es hacer una consulta a cada endpoint por separado y cruzar los resultados del lado del cliente:

Since each dataset lives on its own endpoint, there's no single SPARQL query that joins both. The SERVICE clause (which would allow federating queries across endpoints) isn't available. The correct approach — and the one the Library's own search uses — is to query each endpoint separately and join the results client-side:

const [resTesauro, resCatalogo] = await Promise.all([
  fetch('https://biblioteca.inti.gob.ar/sparql/Tesauro/query?query=...'),
  fetch('https://biblioteca.inti.gob.ar/sparql/Catalogo/query?query=...')
]);
// Cruzá los bindings en tu propio código (por etiqueta, URI, etc.)

Editor de ConsultasQuery Editor

Editor SPARQL interactivo (YASGUI). Hacé clic en «Cargar» en cualquier ejemplo para traerlo acá.

Interactive SPARQL editor (YASGUI). Click "Load" on any example to bring it here.

Por defecto apunta a Catálogo. Para consultar otro dataset, cambiá la URL en la barra de endpoint del editor (ej. reemplazá Catalogo por Tesauro). Points to Catálogo by default. To query another dataset, change the URL in the editor's endpoint bar (e.g., replace Catalogo with Tesauro).

Consumir el Endpoint desde códigoConsuming the Endpoint from Code

Ejemplos contra el dataset Catálogo — cambiá el nombre del dataset en la URL para consultar otro.

Examples against the Catálogo dataset — change the dataset name in the URL to query another.

Shell / curl

curl -G \
  --data-urlencode 'query=PREFIX schema: <http://schema.org/>
SELECT ?uri ?titulo
WHERE {
  ?uri schema:name ?titulo .
  FILTER(CONTAINS(LCASE(STR(?titulo)), "acero"))
} LIMIT 10' \
  -H 'Accept: application/sparql-results+json' \
  'https://biblioteca.inti.gob.ar/sparql/Catalogo/query'

Python · SPARQLWrapper

from SPARQLWrapper import SPARQLWrapper, JSON

endpoint = "https://biblioteca.inti.gob.ar/sparql/Catalogo/query"
sparql = SPARQLWrapper(endpoint)

sparql.setQuery("""PREFIX schema: <http://schema.org/>
SELECT ?uri ?titulo
WHERE {
  ?uri schema:name ?titulo .
  FILTER(CONTAINS(LCASE(STR(?titulo)), "acero"))
} LIMIT 20""")

sparql.setReturnFormat(JSON)
results = sparql.query().convert()
for row in results["results"]["bindings"]:
    print(row["titulo"]["value"])

JavaScript · fetch

const endpoint = 'https://biblioteca.inti.gob.ar/sparql/Catalogo/query';
const query = `PREFIX schema: <http://schema.org/>
SELECT ?uri ?titulo
WHERE {
  ?uri schema:name ?titulo .
  FILTER(CONTAINS(LCASE(STR(?titulo)), "acero"))
} LIMIT 20`;

const url = new URL(endpoint);
url.searchParams.set('query', query);

const response = await fetch(url, {
  headers: { 'Accept': 'application/sparql-results+json' }
});
const data = await response.json();
data.results.bindings.forEach(r => console.log(r.titulo.value));

Términos de uso y LicenciaTerms of Use & License

Límites de usoUsage limits

10 consultas por segundo por IP, con ráfagas de hasta 50. Por encima de eso, HTTP 503.10 queries per second per IP, with bursts of up to 50. Above that, HTTP 503.

30 segundos de timeout por consulta. No hay un tope de filas configurado: una consulta que devolvería demasiados resultados corta por timeout antes de completarse.30-second timeout per query. There's no configured row cap: a query that would return too many results hits the timeout before completing.

Solo lectura: SELECT, ASK, DESCRIBE, CONSTRUCT. La escritura requiere autenticación y no está disponible públicamente.Read-only: SELECT, ASK, DESCRIBE, CONSTRUCT. Writing requires authentication and isn't publicly available.

La cláusula SERVICE (federación con endpoints externos) está deshabilitada.The SERVICE clause (federation with external endpoints) is disabled.

LicenciaLicense

Los metadatos y el grafo RDF publicados en estos 4 datasets (estructura, relaciones, etiquetas, jerarquías) están disponibles bajo Creative Commons Attribution 4.0 International (CC BY 4.0). Podés usarlos, modificarlos y redistribuirlos libremente citando a la Biblioteca INTI.

The metadata and RDF graph published in these 4 datasets (structure, relationships, labels, hierarchies) are available under Creative Commons Attribution 4.0 International (CC BY 4.0). You may use, modify and redistribute freely, crediting the INTI Library.

Esto cubre el grafo de metadatos, no necesariamente los documentos originales (PDFs) a los que algunos registros del Catálogo hacen referencia. Cada uno de esos documentos tiene su propia condición de derechos, indicada por registro cuando corresponde. This covers the metadata graph, not necessarily the original documents (PDFs) that some Catalog records reference. Each of those documents has its own rights status, indicated per record where applicable.

Cómo citar:

How to cite:

Biblioteca INTI — Datos Abiertos Enlazados.
https://biblioteca.inti.gob.ar/endpoint.html
Licencia: CC BY 4.0. Consultado: [fecha].

INTI Library — Linked Open Data.
https://biblioteca.inti.gob.ar/endpoint.html
License: CC BY 4.0. Accessed: [date].

Biblioteca INTISPARQL Endpoint INTI LibrarySPARQL Endpoint

Datasets disponiblesAvailable Datasets

Catálogo Bibliográfico

Bibliographic Catalog

Tesauro INTI

INTI Thesaurus

Diccionarios Técnicos

Technical Dictionaries

Guía de Fuentes

Sources Guide

Prefijos y VocabulariosPrefixes & Vocabularies

Consultas de ejemploExample Queries

Buscar registros por título

Search records by title

Contar registros por tipo de material

Count records by material type

Verificar que el dataset responde

Check the dataset is responding

Listar conceptos del Tesauro

List Thesaurus concepts

Términos más amplios (jerarquía ascendente)

Broader terms (upward hierarchy)

Conceptos enlazados a Wikidata

Concepts linked to Wikidata

Término con traducciones y definición

Term with translations and definition

Fuentes por categoría

Sources by category

¿Y si necesito cruzar dos datasets?What if I need to combine two datasets?

Editor de ConsultasQuery Editor

Consumir el Endpoint desde códigoConsuming the Endpoint from Code

Términos de uso y LicenciaTerms of Use & License

Límites de usoUsage limits

LicenciaLicense

Biblioteca INTI
SPARQL Endpoint INTI Library
SPARQL Endpoint